stdlib/source/test/lux/ffi.rb.lux


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

(.using
 [library
  [lux "*"
   ["_" test {"+" Test}]
   [abstract
    [monad {"+" do}]]
   [math
    ["[0]" random]]]]
 [\\library
  ["[0]" /]]
 ["$[0]" / "_"
  ["[1][0]" export]])

(/.import: File
  "[1]::[0]"
  ("static" SEPARATOR /.String))

(def: .public test
  Test
  (do [! random.monad]
    [boolean random.bit
     integer random.int
     float random.frac
     string (random.ascii/lower 1)]
    (<| (_.covering /._)
        (`` (all _.and
                 (~~ (template [<type> <sample>]
                       [(_.cover [<type>]
                                 (exec
                                   (is <type> <sample>)
                                   true))]

                       [/.Boolean boolean]
                       [/.Integer integer]
                       [/.Float float]
                       [/.String string]
                       ))
                 (_.for [/.Object]
                        (all _.and
                             (~~ (template [<type>]
                                   [(_.cover [<type>]
                                             (exec
                                               (|> []
                                                   (as <type>)
                                                   (is (Ex (_ a) (/.Object a))))
                                               true))]

                                   [/.Nil]
                                   [/.Function]
                                   ))))
                 (_.cover [/.import:]
                          (same? (..File::SEPARATOR)
                                 (..File::SEPARATOR)))

                 $/export.test
                 )))))