blob: f99c9216c8a13b6a265841f88fc260d690a5a130 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
(.module:
[lux (#- type)
[abstract
[predicate (#+ Predicate)]]
["." macro
[syntax (#+ syntax:)]]
["." type
abstract]])
(abstract: #export (Refined t %)
{#value t
#predicate (Predicate t)}
{#.doc "A refined type '%' of base type 't' using a predicate."}
(type: #export (Refiner t %)
(-> t (Maybe (Refined t %))))
(def: #export (refinement predicate)
(All [t]
(Ex [%]
(-> (Predicate t) (Refiner t %))))
(function (_ un_refined)
(if (predicate un_refined)
(#.Some (:abstraction {#value un_refined
#predicate predicate}))
#.None)))
(template [<name> <output> <slot>]
[(def: #export <name>
(All [t %] (-> (Refined t %) <output>))
(|>> :representation (get@ <slot>)))]
[un_refine t #value]
[predicate (Predicate t) #predicate]
)
(def: #export (lift transform)
(All [t %]
(-> (-> t t)
(-> (Refined t %) (Maybe (Refined t %)))))
(function (_ refined)
(let [(^slots [#value #predicate]) (:representation refined)
value' (transform value)]
(if (predicate value')
(#.Some (:abstraction {#value value'
#predicate predicate}))
#.None))))
)
(def: #export (filter refiner values)
(All [t %] (-> (Refiner t %) (List t) (List (Refined t %))))
(case values
#.Nil
#.Nil
(#.Cons head tail)
(case (refiner head)
(#.Some refined)
(#.Cons refined (filter refiner tail))
#.None
(filter refiner tail))))
(def: #export (partition refiner values)
(All [t %] (-> (Refiner t %) (List t) [(List (Refined t %)) (List t)]))
(case values
#.Nil
[#.Nil #.Nil]
(#.Cons head tail)
(let [[yes no] (partition refiner tail)]
(case (refiner head)
(#.Some refined)
[(#.Cons refined yes)
no]
#.None
[yes
(#.Cons head no)]))))
(syntax: #export (type refiner)
(macro.with_gensyms [g!t g!%]
(wrap (list (` ((~! type.:by_example) [(~ g!t) (~ g!%)]
{(..Refiner (~ g!t) (~ g!%))
(~ refiner)}
(..Refined (~ g!t) (~ g!%))))))))
|