{-# LANGUAGE DeriveAnyClass    #-}
{-# LANGUAGE DeriveGeneric     #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE LambdaCase        #-}
{-# LANGUAGE NamedFieldPuns    #-}
{-# LANGUAGE OverloadedStrings #-}

-- | Module that contains the high-level checking functions
module CheckMap (loadAndLintMap, MapResult(..)) where

import           Data.Aeson       (ToJSON)
import qualified Data.Aeson       as A
import           Data.Map         (Map, fromList, toList)
import           Data.Maybe       (mapMaybe)
import           Data.Text        (Text)
import qualified Data.Text        as T
import qualified Data.Vector      as V
import           GHC.Generics     (Generic)


import           Data.Aeson.Types ((.=))
import           LintWriter       (LintResult (..), LintWriter, askContext,
                                   filterLintLevel, lintToDep, resultToDeps,
                                   resultToLints, resultToOffers, runLintWriter)
import           Properties       (checkLayerProperty, checkMap, checkTileset)
import           Tiled2           (Layer (layerName, layerProperties),
                                   LoadResult (..),
                                   Tiledmap (tiledmapLayers, tiledmapTilesets),
                                   Tileset (tilesetName), loadTiledmap)
import           Types            (Dep, Level (..), Lint (..), hint)
import           Util             (PrettyPrint (prettyprint), prettyprint)



-- | What this linter produces: lints for a single map
data MapResult = MapResult
  { mapresultLayer    :: Map Text (LintResult Layer)
  , mapresultTileset  :: Map Text (LintResult Tileset)
  , mapresultGeneral  :: [Lint]
  , mapresultDepends  :: [Dep]
  , mapresultProvides :: [Text]
  } deriving (Generic)

instance ToJSON MapResult where
  toJSON res = A.object
    [ "layer" .= mapresultLayer res
    , "tileset" .= mapresultTileset res
    , "general" .= mapresultGeneral res
    -- TODO: not sure if these are necessary of even useful
    , "depends" .= mapresultDepends res
    , "provides" .= mapresultProvides res
    ]

-- | this module's raison d'être
-- Lints the map at `path`, and limits local links to at most `depth`
-- layers upwards in the file hierarchy
loadAndLintMap :: FilePath -> Int -> IO (Maybe MapResult)
loadAndLintMap path depth = loadTiledmap path >>= pure . \case
    DecodeErr err -> Just $ MapResult
      { mapresultLayer = mempty
      , mapresultTileset = mempty
      , mapresultDepends = []
      , mapresultProvides = []
      , mapresultGeneral =
        [ hint Fatal . T.pack $
          path <> ": Fatal: " <> err
        ]
      }
    IOErr _ -> Nothing
    Loaded waMap ->
      Just (runLinter waMap depth)

-- | lint a loaded map
runLinter :: Tiledmap -> Int -> MapResult
runLinter tiledmap depth = MapResult
  { mapresultLayer = fromList layer
  , mapresultTileset = fromList tileset
  , mapresultGeneral = generalLints
  , mapresultDepends = concatMap (resultToDeps . snd) layer
    <> mapMaybe lintToDep generalLints
    <> concatMap (resultToDeps . snd) tileset
  , mapresultProvides = concatMap (resultToOffers . snd) layer
  }
  where
    layer = V.toList . V.map runCheck $ tiledmapLayers tiledmap
      where runCheck l = (layerName l, runLintWriter l depth checkLayer)
    tileset =  V.toList . V.map runCheck $ tiledmapTilesets tiledmap
      where runCheck l = (tilesetName l, runLintWriter l depth (checkTileset l))

    -- lints collected from properties
    generalLints =
      resultToLints $ runLintWriter tiledmap depth checkMap


-- | collect lints on a single map layer
checkLayer :: LintWriter Layer
checkLayer = do
  layer <- askContext
  mapM_ checkLayerProperty (layerProperties layer)

-- human-readable lint output, e.g. for consoles
instance PrettyPrint (Level, MapResult) where
  prettyprint (level, mapResult) = if prettyLints == ""
    then "  all good!\n" else prettyLints
    where
      prettyLints = T.concat $ prettyGeneral <> prettyLayer
        <> prettyTileset
      -- TODO: this can be simplified further
      prettyLayer :: [Text]
      prettyLayer = mapMaybe
        (\(_,l) -> Just $ prettyprint (level, l))
        (toList . mapresultLayer $ mapResult)
      prettyTileset :: [Text]
      prettyTileset = mapMaybe
        (\(_,t) -> Just $ prettyprint (level, t))
        (toList . mapresultTileset $ mapResult)
      prettyGeneral :: [Text]
      prettyGeneral = map
        ((<> "\n") . prettyprint)
        . filterLintLevel level
        $ mapresultGeneral mapResult