{-# LANGUAGE DataKinds         #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE TypeApplications  #-}
{-# LANGUAGE TypeOperators     #-}

-- | The sole authorative definition of this server's API, given as a Servant-style
-- Haskell type. All other descriptions of the API are generated from this one.
module API (API, CompleteAPI) where

import           Data.Map                 (Map)
import           Data.Proxy               (Proxy (..))
import           Data.Swagger             (Swagger)
import           Data.Swagger.ParamSchema (ToParamSchema (..))
import           Data.Time                (Day, UTCTime)
import           GTFS
import           Persist
import           Servant                  (Application,
                                           FromHttpApiData (parseUrlPiece),
                                           Server, err401, err404, serve,
                                           throwError, type (:>))
import           Servant.API              (Capture, FromHttpApiData, Get, JSON,
                                           Post, QueryParam, ReqBody,
                                           type (:<|>) ((:<|>)))

-- | The server's API (as it is actually intended).
type API = "stations" :> Get '[JSON] (Map StationID Station)
  :<|> "timetable" :> Capture "Station ID" StationID :> QueryParam "day" Day :> Get '[JSON] (Map TripID (Trip Deep))
  :<|> "trip" :> Capture "Trip ID" TripID :> Get '[JSON] (Trip Deep)
  -- ingress API (put this behind BasicAuth?)
  -- TODO: perhaps require a first ping for registration?
  :<|> "train" :> "register" :> Capture "Trip ID" TripID :> Post '[JSON] Token
  -- TODO: perhaps a websocket instead?
  :<|> "train" :> "ping" :> ReqBody '[JSON] TripPing :> Post '[JSON] ()
  -- debug things
  :<|> "debug" :> "state" :> Get '[JSON] (Map Token [TripPing])

-- | The server's API with an additional debug route for accessing the specification
-- itself. Split from API to prevent the API documenting the format in which it is
-- documented, which would be silly and way to verbose.
type CompleteAPI = "debug" :> "openapi" :> Get '[JSON] Swagger
  :<|> API


instance ToParamSchema (Maybe UTCTime) where
  toParamSchema _ = toParamSchema (Proxy @UTCTime)

{-
TODO:
there should be a basic API allowing the questions:
 - what are the next trips leaving from $station? (or $geolocation?)
 - all stops of a given tripID

then the "ingress" API:
 - train ping (location, estimated delay, etc.)
 - cancel trip
 - add trip?

-}