{ inputs, ... }:
self: super:

let
  unstable = inputs.nixpkgs-unstable.legacyPackages.${self.system};
  crs-tools = self.callPackage ./crs-tools.nix {};
  rustPlatform = self.makeRustPlatform {
    cargo = self.rust-bin.stable.latest.minimal;
    rustc = self.rust-bin.stable.latest.minimal;
  };
  radicle = import ./radicle.nix;
in
{
  galmon-core = self.callPackage (import ./galmon.nix {}) {};
  galmon-full = self.callPackage (import ./galmon.nix { buildAll = true; }) {};

  glitchtip = (self.callPackage ./glitchtip.nix {
    python = super.python310.override ({
      packageOverrides = self: super: {
        django = super.django_4;
      };
    });
  });

  almanac = self.rustPlatform.buildRustPackage rec {
    pname = "almanac";
    version = "git";
    src = inputs.almanac.outPath;
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  rustex = rustPlatform.buildRustPackage rec {
    pname = "rustex";
    version = "git";
    src = "${self.fetchFromGitHub {
      owner = "slatex";
      repo = "RusTeX";
      rev = "74f9d13d4a88e32a32c5d8b10e5ae1a2442a7a92";
      sha256 = "sha256-SOnqb/ptMoPI+G96nI/dQHOsvjlaDa6YSBEjy77kRdY=";
    }}/rustex";
    # patches = [ ./rustex.patch ];
    postPatch = ''
      ln -s ${./rustex-cargo.lock} Cargo.lock
    '';
    cargoLock.lockFile = ./rustex-cargo.lock;
    doCheck = false;
  };

  kijetesantakaluotokieni = self.rustPlatform.buildRustPackage rec {
    pname = "kijetesantakaluotokieni";
    version = "git";
    src = self.fetchgit {
      url = "https://git.2ki.xyz/spiders/kijetesantakaluotokieni";
      rev = "7d9ea828f42ffd9fb6826ea4cbf7677b08222064";
      sha256 = "sha256-PEp+K5mRNUR6yWLrpGpiX8qvaPQIibA17NQwXUiC2lk=";
    };
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  showrt = self.rustPlatform.buildRustPackage rec {
    pname = "showrt";
    version = "git";
    src = inputs.showrt;
    nativeBuildInputs = [ self.protobuf ];
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  isabelle-utils = self.rustPlatform.buildRustPackage rec {
    pname = "isabelle-utils";
    version = "git";
    src = inputs.isabelle-utils;
    cargoLock.lockFile = "${src}/Cargo.lock";
    doCheck = false;
  };

  isabat = import "${inputs.isabelle-utils}/isabat.nix" {
    pkgs = self;
    isabelle-rust-utils = self.isabelle-utils;
  };

  crs-tracker = crs-tools.tracker;
  crs-php = crs-tools.php;

  travelynx = self.callPackage ./travelynx.nix {};

  beamPackages = super.beam.packagesWith self.erlang;
  elixir = self.beamPackages.elixir_1_14;
  erlang = super.erlang_nox;

  bahnhof-name = let
    inherit (self.callPackage "${inputs.nix-gleam.outPath}/builder/default.nix" {}) buildGleamApplication;
  in buildGleamApplication {
    version = "0.1";
    pname = "bahnhof.name";
    src = inputs.bahnhof-name;

    postInstall = ''
      cp -r $src/data $out
    '';
  };

  matrix-to = self.callPackage ./matrix-to.nix {};

  inherit (unstable) lean4;

  hikari_unstable = (unstable.hikari.overrideAttrs (old: {
    src = /home/stuebinm/clones/hikari;
    buildInputs = old.buildInputs ++ [ self.pandoc self.xorg.xcbutilwm.dev ]; #self.libdrm self.libdrm.dev ];
    makeFlags = with self.lib;
      [ "PREFIX=$(out)" "WITH_POSIX_C_SOURCE=YES"
        "WITH_GAMMACONTROL=YES" "WITH_LAYERSHELL=YES" "WITH_SCREENCOPY=YES" ];
  })).override { wlroots = unstable.wlroots_0_16; stdenv = self.clangStdenv; };

  heartwood = self.callPackage radicle.heartwood { inherit (rustPlatform) buildRustPackage; };

  radicle-interface = self.callPackage radicle.interface {};

  radicle-tui = self.callPackage radicle.tui { inherit (rustPlatform) buildRustPackage; };
}