{ inputs, ... }:
self: super:

let
  unstable = inputs.nixpkgs-unstable.legacyPackages.${self.system};
  oldstable = inputs.nixpkgs-oldstable.legacyPackages.${self.system};
  crs-tools = self.callPackage ./crs-tools.nix {};
in
{
  galmon-core = self.callPackage (import ./galmon.nix {}) {};
  galmon-full = self.callPackage (import ./galmon.nix { buildAll = true; }) {};

  glitchtip = (self.callPackage ./glitchtip.nix {
    python = super.python310.override ({
      packageOverrides = self: super: {
        django = super.django_4;
      };
    });
  });

  almanac = self.rustPlatform.buildRustPackage rec {
    pname = "almanac";
    version = "git";
    src = inputs.almanac.outPath;
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  rustex = self.rustPlatform.buildRustPackage rec {
    pname = "rustex";
    version = "git";
    src = self.fetchFromGitHub {
      owner = "slatex";
      repo = "RusTeX";
      rev = "3a6236016505d8377f6b7f9f162d812cd66a0c74";
      sha256 = "sha256-dJgk4Rw5OvqKrL0eg/crAVjK2dyF61Kb/rqQqHTkRkw=";
    };
    postPatch = ''
      rm -rf src
      mv rustex/Cargo.toml .
      mv rustex/src .
      ln -s ${./rustex-cargo.lock} Cargo.lock
    '';
    cargoLock.lockFile = ./rustex-cargo.lock;
    doCheck = false;
  };

  kijetesantakaluotokieni = self.rustPlatform.buildRustPackage rec {
    pname = "kijetesantakaluotokieni";
    version = "git";
    src = self.fetchgit {
      url = "https://git.2ki.xyz/spiders/kijetesantakaluotokieni";
      rev = "7d9ea828f42ffd9fb6826ea4cbf7677b08222064";
      sha256 = "sha256-PEp+K5mRNUR6yWLrpGpiX8qvaPQIibA17NQwXUiC2lk=";
    };
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  showrt = self.rustPlatform.buildRustPackage rec {
    pname = "showrt";
    version = "git";
    src = inputs.showrt;
    nativeBuildInputs = [ self.protobuf ];
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  isabelle-utils = self.rustPlatform.buildRustPackage rec {
    pname = "isabelle-utils";
    version = "git";
    src = inputs.isabelle-utils;
    cargoLock.lockFile = "${src}/Cargo.lock";
    checkPhase = "
      echo skipping tests
    ";
  };

  isabat = import "${inputs.isabelle-utils}/isabat.nix" {
    pkgs = self;
    isabelle-rust-utils = self.isabelle-utils;
  };

  crs-tracker = crs-tools.tracker;
  crs-php = crs-tools.php;

  travelynx = self.callPackage ./travelynx.nix {};

  beamPackages = super.beam.packagesWith self.erlang;
  elixir = self.beamPackages.elixir_1_14;
  erlang = super.erlang_nox;

  bahnhof-name = let
    inherit (self.callPackage "${inputs.nix-gleam.outPath}/builder/default.nix" {}) buildGleamApplication;
  in buildGleamApplication {
    version = "0.1";
    pname = "bahnhof.name";
    src = inputs.bahnhof-name;

    postInstall = ''
      cp -r $src/data $out
    '';
  };

  mu = oldstable.mu;

  matrix-to = self.callPackage ./matrix-to.nix {};

  lean4 = unstable.lean4.overrideAttrs (old: rec {
    version = "4.1.0-rc1";
    src = self.fetchFromGitHub {
      owner = "leanprover";
      repo = "lean4";
      rev = "v${version}";
      hash = "sha256-OQ72uweFMSkOzJ9u92enNql48ReZ+NBlnXtnanH+ZVA=";
    };
    postPatch = ''
      substituteInPlace src/CMakeLists.txt \
        --replace 'set(GIT_SHA1 "")' 'set(GIT_SHA1 "${src.rev}")'

      # Remove tests that fails in sandbox.
      # It expects `sourceRoot` to be a git repository.
      rm -rf src/lake/examples/git/
    '';
  });
}