{ inputs, ... }:
self: super:

let
  unstable = inputs.nixpkgs-unstable.legacyPackages.${self.system};
  crs-tools = self.callPackage ./crs-tools.nix {};
  rustPlatform = self.makeRustPlatform {
    cargo = self.rust-bin.stable.latest.minimal;
    rustc = self.rust-bin.stable.latest.minimal;
  };
  radicle = import ./radicle.nix;
in
{
  beamPackages = super.beam.packagesWith self.erlang;
  elixir = self.beamPackages.elixir;
  erlang = super.erlang_nox;

  inherit (unstable) lean4;


  git-annex-remote-remarkable2 = self.callPackage
    ({ rustPlatform, fetchgit, ... }:
      rustPlatform.buildRustPackage rec {
        name = "git-annex-remote-remarkable2";
        src = fetchgit {
          url = "https://stuebinm.eu/git/git-annex-remote-remarkable2";
          rev = "refs/heads/main";
          hash = "sha256-ZDoZFFADti3ZwLZqeP/F3BbW+Csuprw6+1LBBQIjnlo=";
        };
        cargoLock.lockFile = "${src.outPath}/Cargo.lock";
      }) { };

  #### packages which are actually in use somewhere ####

  galmon-core = self.callPackage ./galmon.nix {};
  galmon-full = self.callPackage ./galmon.nix { buildAll = true; };

  hikari = super.hikari.overrideAttrs (old: {
    makeFlags = old.makeFlags ++ [ "DEBUG=YES" ];
    patches = [ ./patches/hikari-gtk4.patch ];
  });

  akkoma-fe = super.akkoma-frontends.akkoma-fe.overrideAttrs (old: {
    patches = [ ./patches/akkoma-fe-toki-pona.patch ];
  });

  akkoma = super.akkoma.overrideAttrs (old: {
    patches = [ ./patches/akkoma-toki-pona.patch ];
  });

  cgit = super.cgit.overrideAttrs (old: {
    patches = [ ./patches/cgit-main-instead-of-master.patch ];
  });

  almanac = self.rustPlatform.buildRustPackage rec {
    pname = "almanac";
    version = "git";
    src = inputs.almanac.outPath;
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  rustex = rustPlatform.buildRustPackage rec {
    pname = "rustex";
    version = "git";
    src = "${self.fetchFromGitHub {
      owner = "slatex";
      repo = "RusTeX";
      rev = "74f9d13d4a88e32a32c5d8b10e5ae1a2442a7a92";
      sha256 = "sha256-SOnqb/ptMoPI+G96nI/dQHOsvjlaDa6YSBEjy77kRdY=";
    }}/rustex";
    postPatch = ''
      ln -s ${./patches/rustex-cargo.lock} Cargo.lock
    '';
    cargoLock.lockFile = ./patches/rustex-cargo.lock;
    doCheck = false;
  };

  kijetesantakaluotokieni = self.rustPlatform.buildRustPackage rec {
    pname = "kijetesantakaluotokieni";
    version = "git";
    src = self.fetchgit {
      url = "https://git.2ki.xyz/spiders/kijetesantakaluotokieni";
      rev = "7d9ea828f42ffd9fb6826ea4cbf7677b08222064";
      sha256 = "sha256-PEp+K5mRNUR6yWLrpGpiX8qvaPQIibA17NQwXUiC2lk=";
    };
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  showrt = self.rustPlatform.buildRustPackage rec {
    pname = "showrt";
    version = "git";
    src = inputs.showrt;
    nativeBuildInputs = [ self.protobuf ];
    cargoLock.lockFile = "${src}/Cargo.lock";
  };

  isabelle-utils = self.rustPlatform.buildRustPackage rec {
    pname = "isabelle-utils";
    version = "git";
    src = inputs.isabelle-utils;
    cargoLock.lockFile = "${src}/Cargo.lock";
    doCheck = false;
  };

  isabat = import "${inputs.isabelle-utils}/isabat.nix" {
    pkgs = self;
    isabelle-rust-utils = self.isabelle-utils;
  };

  ntfy-matrix-bot = rustPlatform.buildRustPackage rec {
    pname = "ntfy-matrix-bot";
    version = "0.10";
    src = inputs.ntfy-matrix-bot;
    cargoLock.lockFile = "${src}/Cargo.lock";
    doCheck = false;
    meta.mainProgram = "ntfy-matrix-bot";
  };

  element-web-unwrapped = super.element-web-unwrapped.overrideAttrs {
    patches = [ ./patches/element-css.patch ];
    # the below patches the javascript's assumptions about box height
    # in the left side bar so that hiding overflow will work correctly
    # should be .mx_RoomTile's height + 12px
    preBuild = ''
      substituteInPlace node_modules/matrix-react-sdk/src/stores/room-list/ListLayout.ts \
        --replace "TILE_HEIGHT_PX = 44" "TILE_HEIGHT_PX = 32"
    '';
  };

  bahnhof-name =
    let
      haskellPkgs = self.haskellPackages.override (old: {
        overrides = self': super': with self.haskell.lib; {
          fuzzyfind = unmarkBroken (doJailbreak super'.fuzzyfind);
          fuzzyset = unmarkBroken (doJailbreak super'.fuzzyset);
        };
      });
      pkg = { mkDerivation, base, bytestring, cassava, containers
            , fuzzyfind, fuzzyset, http-client, http-client-openssl, http-types
            , lib, stm, text, time, vector, wai, wai-extra, warp
            }:
              mkDerivation {
                pname = "bahnhof.name";
                version = "0.2.0.0";
                src = inputs.bahnhof-name;
                isLibrary = false;
                isExecutable = true;
                executableHaskellDepends = [
                  base bytestring cassava containers fuzzyfind fuzzyset http-client
                  http-client-openssl http-types stm text time vector wai wai-extra
                  warp
                ];
                mainProgram = "bahnhof-name";
                license = lib.licenses.eupl12;
                postInstall = ''
                  cp -r $src/data $out
                '';
              };
    in
      haskellPkgs.callPackage pkg {};

  nomsring = super.haskellPackages.callPackage ./nomsring {};

  #### sporadically maintained / updated ####

  hikari_unstable = (unstable.hikari.overrideAttrs (old: {
    src = /home/stuebinm/clones/hikari;
    buildInputs = old.buildInputs ++ [ self.pandoc self.xorg.xcbutilwm.dev ]; #self.libdrm self.libdrm.dev ];
    makeFlags = with self.lib;
      [ "PREFIX=$(out)" "WITH_POSIX_C_SOURCE=YES"
        "WITH_GAMMACONTROL=YES" "WITH_LAYERSHELL=YES" "WITH_SCREENCOPY=YES" ];
  })).override { wlroots = unstable.wlroots_0_16; stdenv = self.clangStdenv; };

  travelynx = self.callPackage ./travelynx.nix {};



  #### packaged mostly as shitpost / to play around with ####

  bookwyrm = (self.callPackage ./bookwyrm.nix {
    python = super.python311.override ({
      packageOverrides = self: super: {
        django = super.django_3;
        python-crontab = super.python-crontab.overridePythonAttrs (_: { doCheck = false; });
        django-sass-processor = self.callPackage ./python/django-sass-processor.nix {};
        django-imagekit = self.callPackage ./python/django-imagekit.nix {};
        bw-file-resubmit = self.callPackage ./python/bw-file-resubmit.nix {};
      };
    });
  });

  # currently broken because poetry2nix was moved out of nixpkgs
  # glitchtip = (self.callPackage ./glitchtip.nix {
  #   python = super.python310.override ({
  #     packageOverrides = self: super: {
  #       django = super.django_4;
  #     };
  #   });
  # });

  crs-tracker = crs-tools.tracker;
  crs-php = crs-tools.php;

  matrix-to = self.callPackage ./matrix-to.nix {};

  heartwood = self.callPackage radicle.heartwood { inherit (rustPlatform) buildRustPackage; };
  radicle-interface = self.callPackage radicle.interface {};
  radicle-tui = self.callPackage radicle.tui { inherit (rustPlatform) buildRustPackage; };

  inweb = self.callPackage ({stdenv, gnumake, fetchFromGitHub}: stdenv.mkDerivation rec {
    pname = "inweb";
    version = "v7.2.0";
    src = fetchFromGitHub {
      repo = "inweb";
      owner = "ganelson";
      rev = version;
      hash = "sha256-kgyMzqGyZ1aihx8f9OCFOd2dlAUhUp98ni4rcgNrPq0=";
    };

    buildPhase = ''
      ln -s . inweb
      bash inweb/scripts/first.sh linux
    '';

    installPhase = ''
      mkdir -p $out/bin
      cp Tangled/inweb $out/bin
    '';
  }) {};

  # mollysocket = self.callPackage ./mollysocket.nix { };
  mollysocket = inputs.nixpkgs-review.legacyPackages.x86_64-linux.mollysocket;
}