(.using
 [library
  [lux (.except all)
   ["_" test (.only Test)]
   [data
    [collection
     ["[0]" list]
     ["[0]" set (.only Set)]]]
   [macro
    ["[0]" template]]
   [math
    [number
     ["n" nat]]]]]
 [\\library
  ["[0]" / (.only)
   ["/[1]" //]]])

(with_expansions [<categories> (these [informational
                                       [/.continue
                                        /.switching_protocols
                                        /.processing
                                        /.early_hints]]
                                      [success
                                       [/.ok
                                        /.created
                                        /.accepted
                                        /.non_authoritative_information
                                        /.no_content
                                        /.reset_content
                                        /.partial_content
                                        /.multi_status
                                        /.already_reported
                                        /.im_used]]
                                      [redirection
                                       [/.multiple_choices
                                        /.moved_permanently
                                        /.found
                                        /.see_other
                                        /.not_modified
                                        /.use_proxy
                                        /.switch_proxy
                                        /.temporary_redirect
                                        /.permanent_redirect]]
                                      [client
                                       [/.bad_request
                                        /.unauthorized
                                        /.payment_required
                                        /.forbidden
                                        /.not_found
                                        /.method_not_allowed
                                        /.not_acceptable
                                        /.proxy_authentication_required
                                        /.request_timeout
                                        /.conflict
                                        /.gone
                                        /.length_required
                                        /.precondition_failed
                                        /.payload_too_large
                                        /.uri_too_long
                                        /.unsupported_media_type
                                        /.range_not_satisfiable
                                        /.expectation_failed
                                        /.im_a_teapot
                                        /.misdirected_request
                                        /.unprocessable_entity
                                        /.locked
                                        /.failed_dependency
                                        /.upgrade_required
                                        /.precondition_required
                                        /.too_many_requests
                                        /.request_header_fields_too_large
                                        /.unavailable_for_legal_reasons]]
                                      [server
                                       [/.internal_server_error
                                        /.not_implemented
                                        /.bad_gateway
                                        /.service_unavailable
                                        /.gateway_timeout
                                        /.http_version_not_supported
                                        /.variant_also_negotiates
                                        /.insufficient_storage
                                        /.loop_detected
                                        /.not_extended
                                        /.network_authentication_required]])]
  (def all
    (List //.Status)
    (list.together (`` (list (~~ (with_template [<category> <status+>]
                                   [((is (-> Any (List //.Status))
                                         (function (_ _)
                                           (`` (list (~~ (template.spliced <status+>))))))
                                     123)]
                                   
                                   <categories>))))))
  
  (def unique
    (Set //.Status)
    (set.of_list n.hash ..all))

  (def verdict
    (n.= (list.size ..all)
         (set.size ..unique)))

  (with_template [<category> <status+>]
    [(def <category>
       Test
       (_.coverage <status+>
         ..verdict))]
    
    <categories>)

  (def .public test
    Test
    (<| (_.covering /._)
        (`` (.all _.and
                  (~~ (with_template [<category> <status+>]
                        [<category>]
                        
                        <categories>))
                  ))))
  )