(.require
 [library
  [lux (.except)
   [data
    ["[0]" text (.only)
     ["%" \\format (.only format)]]]
   [world
    [file (.only Path)]
    [net
     [uri (.only URI)
      ["[0]" path]]]]]]
 ["[0]" //
  ["[1][0]" artifact (.only Artifact)]])

(def remote_file
  Path
  "maven-metadata.xml")

(def .public (remote_artifact_uri artifact)
  (-> Artifact URI)
  (let [/ path.separator]
    (format (//artifact.directory / (the //artifact.#group artifact))
            / (the //artifact.#name artifact)
            / (the //artifact.#version artifact)
            / ..remote_file)))

(def .public (remote_project_uri artifact)
  (-> Artifact URI)
  (let [/ path.separator]
    (format (//artifact.directory / (the //artifact.#group artifact))
            / (the //artifact.#name artifact)
            / ..remote_file)))

(def local_file
  Path
  "maven-metadata-local.xml")

(def .public (local_uri remote_uri)
  (-> URI URI)
  (text.replaced_once ..remote_file ..local_file remote_uri))

(def .public (remote_uri local_uri)
  (-> URI URI)
  (text.replaced_once ..local_file ..remote_file local_uri))