(.module:
  [library
   [lux {"-" local}
    [abstract
     [equivalence {"+" Equivalence}]
     [hash {"+" Hash}]]
    [control
     [pipe {"+" case>}]]
    [data
     ["[0]" name]
     [text
      ["%" format {"+" Format}]]]
    [math
     [number
      ["n" nat]]]]]
  ["[0]" / "_"
   ["[1][0]" variable {"+" Variable}]])

(type: .public Constant
  Name)

(type: .public Reference
  (Variant
   {#Variable Variable}
   {#Constant Constant}))

(implementation: .public equivalence
  (Equivalence Reference)

  (def: (= reference sample)
    (case [reference sample]
      (^template [<tag> <equivalence>]
        [[{<tag> reference} {<tag> sample}]
         (# <equivalence> = reference sample)])
      ([#Variable /variable.equivalence]
       [#Constant name.equivalence])

      _
      false)))

(implementation: .public hash
  (Hash Reference)

  (def: &equivalence
    ..equivalence)

  (def: (hash value)
    (case value
      (^template [<factor> <tag> <hash>]
        [{<tag> value}
         (|> value
             (# <hash> hash)
             (n.* <factor>))])
      ([2 #Variable /variable.hash]
       [3 #Constant name.hash])
      )))

(template [<name> <family> <tag>]
  [(template: .public (<name> content)
     [(<| {<family>}
          {<tag>}
          content)])]

  [local   ..#Variable /variable.#Local]
  [foreign ..#Variable /variable.#Foreign]
  )

(template [<name> <tag>]
  [(template: .public (<name> content)
     [(<| {<tag>}
          content)])]

  [variable ..#Variable]
  [constant ..#Constant]
  )

(def: .public self
  Reference
  (..local 0))

(def: .public format
  (Format Reference)
  (|>> (case> {#Variable variable}
              (/variable.format variable)
              
              {#Constant constant}
              (%.name constant))))