From b4d0eba7485caf0c6cf58de1193a9114fa273d8b Mon Sep 17 00:00:00 2001
From: Eduardo Julian
Date: Sat, 30 May 2020 15:19:28 -0400
Subject: Split new-luxc into lux-jvm and lux-r.

---
 .../source/luxc/lang/translation/jvm/program.lux   | 82 ++++++++++++++++++++++
 1 file changed, 82 insertions(+)
 create mode 100644 lux-jvm/source/luxc/lang/translation/jvm/program.lux

(limited to 'lux-jvm/source/luxc/lang/translation/jvm/program.lux')

diff --git a/lux-jvm/source/luxc/lang/translation/jvm/program.lux b/lux-jvm/source/luxc/lang/translation/jvm/program.lux
new file mode 100644
index 000000000..7ac897009
--- /dev/null
+++ b/lux-jvm/source/luxc/lang/translation/jvm/program.lux
@@ -0,0 +1,82 @@
+(.module:
+  [lux #*
+   [target
+    [jvm
+     ["$t" type]]]]
+  [luxc
+   [lang
+    [host
+     ["_" jvm
+      ["$d" def]
+      ["$i" inst]]]
+    [translation
+     ["." jvm
+      ["." runtime]]]]])
+
+(def: #export class "LuxProgram")
+
+(def: ^Object ($t.class "java.lang.Object" (list)))
+
+(def: #export (program programI)
+  (-> _.Inst _.Definition)
+  (let [nilI runtime.noneI
+        num-inputsI (|>> ($i.ALOAD 0) $i.ARRAYLENGTH)
+        decI (|>> ($i.int +1) $i.ISUB)
+        headI (|>> $i.DUP
+                   ($i.ALOAD 0)
+                   $i.SWAP
+                   $i.AALOAD
+                   $i.SWAP
+                   $i.DUP_X2
+                   $i.POP)
+        pairI (|>> ($i.int +2)
+                   ($i.ANEWARRAY ..^Object)
+                   $i.DUP_X1
+                   $i.SWAP
+                   ($i.int +0)
+                   $i.SWAP
+                   $i.AASTORE
+                   $i.DUP_X1
+                   $i.SWAP
+                   ($i.int +1)
+                   $i.SWAP
+                   $i.AASTORE)
+        consI (|>> ($i.int +1)
+                   ($i.string "")
+                   $i.DUP2_X1
+                   $i.POP2
+                   runtime.variantI)
+        prepare-input-listI (<| $i.with-label (function (_ @loop))
+                                $i.with-label (function (_ @end))
+                                (|>> nilI
+                                     num-inputsI
+                                     ($i.label @loop)
+                                     decI
+                                     $i.DUP
+                                     ($i.IFLT @end)
+                                     headI
+                                     pairI
+                                     consI
+                                     $i.SWAP
+                                     ($i.GOTO @loop)
+                                     ($i.label @end)
+                                     $i.POP))
+        feed-inputsI ($i.INVOKEVIRTUAL jvm.$Function runtime.apply-method (runtime.apply-signature 1))
+        run-ioI (|>> ($i.CHECKCAST jvm.$Function)
+                     $i.NULL
+                     ($i.INVOKEVIRTUAL jvm.$Function runtime.apply-method (runtime.apply-signature 1)))
+        main-type ($t.method [(list ($t.array ($t.class "java.lang.String" (list))))
+                              $t.void
+                              (list)])]
+    [..class
+     ($d.class #_.V1_6
+               #_.Public _.finalC
+               ..class
+               (list) ..^Object
+               (list)
+               (|>> ($d.method #_.Public _.staticM "main" main-type
+                               (|>> programI
+                                    prepare-input-listI
+                                    feed-inputsI
+                                    run-ioI
+                                    $i.RETURN))))]))
-- 
cgit v1.2.3